主要透過翻頁來濃縮一些技能
個人範例是
1英勇躍擊翻英勇躍擊
2衝鋒阻擾翻衝鋒阻擾
3鍵嗜血翻斬殺一
4鍵旋風翻斬殺二
5鍵暴怒翻斬殺一
6鍵第2層天賦
X刺耳翻刺耳
Z拳擊翻拳擊
C嘲諷翻嘲諷
V狂怒恢復翻嗜血
T魯莽翻斬殺一
Y狂暴之怒不翻
G碎甲投擲不翻
這裡主要提供翻頁架構,
巨集的東西最好是自己理解後修改橙適合自己習慣
沒有絕對最好
#showtooltip
/開始攻擊
/連續施法 [@mouseover,harm][harm][] reset=3 狂怒恢復,嗜血
/施放 勝利衝擊
/施放 無視苦痛
/施放 振奮咆哮
/使用 治療石
/使用 上古治療藥水
/使用 挑戰藥水
/施放 魯莽
/使用 漫溢的燼火之鏡
/切換快捷列 1 2
利用狂怒恢復無GCD的特性,配合連續施法
可以讓狂怒恢復即使CD也能放出有GCD的勝利衝擊
也能保證嗜血是放在狂怒恢復之後
#showtooltip 嗜血
/cqs
/開始攻擊
/連續施法 [worn:盾牌,harm] reset=1.5/nocombat 嗜血,盾牌猛擊,盾牌格擋
/連續施法 [harm] reset=1/nocombat 嗜血,狂怒之擊,暴怒
/切換快捷列 1 2
#showtooltip 魯莽
/equipset 雙
/連續施法 魯莽
/use 狂暴(種族特長)
/use 盬水藥水
/使用 戰鬥之焰
/使用 罪惡鬥士兇猛徽章
/use 無束志士兇猛徽章
/連續施法 [talent:7/3] reset=2 旋風斬,破陣突圍,暴怒
/切換快捷列 1 2
由於與斬殺一互翻,所以爆發循環怒氣會足夠放暴怒
盡情放縱天賦之下的魯莽會使嗜血變成高傷害的浴血(65%AP=>100%AP)浴血WOWHEAD連結
狂怒之擊變成可衝鋒且主副手都提高傷害的碾擊(61.1%=>94%)碾擊WOWHEAD連結
#showtooltip 拳擊
/施放 [@mouseover,harm][@focus,harm][harm]衝鋒
/施放 [@mouseover,harm][@focus,harm][harm]拳擊
/施放 [@mouseover,harm][@focus,harm][harm]斬殺
/切換快捷列 1 2
若有點死刑可以做15碼遠程斷法,若無也能以衝鋒做遠程斷法
#showtooltip 斬殺
/開始攻擊
/連續施法 [@mouseover,harm][harm][] reset=1/target 斬殺
/切換快捷列 1 2
斬殺一
只對鼠標或當前目標斬殺,加入旋風斬也是盡可能有AE BUFF
#showtooltip 斬殺
/施放 [@mouseover,harm,nodead]斬殺
/清除目標
/targetlasttarget
/targetenemy
/連續施法 [harm] reset=1 斬殺
/targetlasttarget
/清除目標
/targetlasttarget
/切換快捷列 1 2
斬殺二
這個斬殺是不變換當前目標尋找其他可斬殺目標
若有定罪, 則80%以上HP都會斬
但是目前無法對當前目標斬殺,所以特別與斬殺一分開
大部分的技能都是與斬殺一做互翻,
但只有斬殺二配合旋風斬互翻會比較不影響輸出並兼顧到AE效率
#showtooltip 旋風斬
/連續施法 reset=1 旋風斬,斬殺
/切換快捷列 1 2
嘗試對當前目標斬殺,配合狂按翻斬殺二,若當前目標無法斬殺,則嘗試斬殺附近的怪
#showtooltip 暴怒
/cqs
/equipset 雙雙
/取消光環 劍刃風暴
/施放 魯莽
/施放 血怒
/開始攻擊
/連續施法 [harm] reset=1 暴怒,狂怒之擊
/施放 狂暴(種族特長)
/use 盬水藥水
/施放 罪惡鬥士兇猛徽章
/施放 無束志士兇猛徽章
/切換快捷列 1 2
#showtooltip 破膽怒吼
/清除目標
/開始攻擊
/施放 [@mouseover,harm][@focus,harm][harm][]破膽怒吼
加上開始攻擊自動鎖定最近目標恐懼
最主要是在PVP混戰中快速找一個可施放目標放恐懼
/開始攻擊與/targetenemy 的差異在於
開始攻擊只要有當前目標就不會再切換目標
而/targetenemy 會一直切
#showtooltip 英勇躍擊
/dismount
/cancelaura 劍刃風暴
/cast [@cursor]英勇躍擊
/cast 法術反射
/施放 [harm]勝利衝擊
/使用 巨大的巨魔頭
/使用 重製的魔能聚焦器
/使用 琪瑞安鳴鐘
就是追法系或獵人時順便開反射,有時正好可以踩到陷阱反射回去
#showtooltip
/連續施法 [@mouseover,nodead,help] reset=10 阻擾,法術反射;[ @mouseover,nodead,harm] reset=2 衝鋒,勝利衝擊
/施放 [@mouseover,harm]斷筋
/連續施法 [harm] reset=2 衝鋒,勝利衝擊
/連續施法 [help][@targettarget,help] reset=10 阻擾,法術反射
/施放 [harm]斷筋
/取消光環 劍刃風暴
/切換快捷列 1 2
鼠標衝鋒阻擾外帶斷筋反射勝利衝擊
另外目標的目標是友方會優先阻擾
衝鋒若CD時是無法放到勝利衝擊的,但是可以隨時放斷筋,
原理是無GCD的技能若正在CD也能繼續放其他技能
所以利用/castsequence 錯開
#showtooltip [talent:2/3]暴風怒擲;[talent:2/2]勝利在望;[talent:2/1]衝鋒
/use [group]遠古戰役藥水
/清除目標
/開始攻擊
/cast [@mouseover,harm][@focus,harm][harm]暴風怒擲
/cast [talent:2/1]衝鋒
/cast [harm,nodead]勝利在望
第2層天賦
#showtooltip [talnet:6/3]劍刃風暴;[talent:6/2]龍吼
/cast [worn:盾牌]盾牌格檔
/equipset 雙
/cast 狂暴(種族特長)
/cast 狂怒恢復
/cast 無視苦痛
/cast 魯莽
/cast 法術反射
/use 遠古戰役藥水
/use 14
/use [mod:alt,talent:6/3][talent:6/3,btn:2]6
/連續施法 reset=10 劍刃風暴,振奮咆哮
/連續施法 reset=2 龍吼
/切換快捷列 1 2
第6層天賦
其中 /use [mod:alt][btn:2]6 是用來放工程火箭鞋(腰帶位置)
最主要用來讓劍刃風暴可以方便高速追人或解定快速逃跑
由於扛旗時用火箭鞋會掉旗子,
所以只有配合ALT鍵或滑鼠右鍵點擊才會增放火箭鞋能力
增加限定大風車天賦才放火箭鞋
#showtooltip
/連續施法 [@mouseover,harm][harm][]碎甲投擲
以往就是用用來破無敵或冰箱的東西
不過九版技能說明增加了可破除魔法免疫效果
以及對有吸收護盾的目標增加500%傷害
盲猜可能獵人護盾或DK綠盾也有效果
至於500%傷害應該就是把吸收盾打掉而已
#showtooltip 狂怒之擊
/開始攻擊
/連續施法 [@mouseover,harm][harm] reset=2/nocombat 狂怒之擊,斬殺
/切換快捷列 1 2
#showtooltip
/cast 法術反射
#showtooltip
/equipset [noworn:盾牌]盾
/連續施法 [worn:盾牌] reset=3 盾牌格擋,無視苦痛
#showtooltip
/使用 罪惡志士勳章
/施放 法術反射
/施放 無視苦痛
/施放 魯莽
/清除目標
/開始攻擊
/連續施法 reset=1.5 狂怒恢復,嗜血
/施放 [worn:盾牌]盾牌格擋
/施放 破膽怒吼
由於這版本戰士實在太軟,所以需要解控瞬邊開滿救命大招
魯莽是因為第七層點了給怒氣天賦,若怒氣不足以開苦痛,按第二次就會開到苦痛
#showtooltip
/cast 刺耳怒吼
/cast [harm]斷筋
另外說明裝備指令有三大類
第一種:
/equip 裝備名稱
這個通常適合只有一個部位的裝備,系統會自動找位置裝上去
但若是武器、飾品、戒指就得用第二種指定部位,
不然系統只會放第一個
第二種:
/equipslot 裝備部位代碼 裝備名稱
裝備部位代碼
主手:16 / 副手:17 / 上飾品:13 / 下飾品:14
因為戰鬥中能換的裝備只有武器盾牌
所以我們只會用到 16 17
/equipslot 16 主手武器名稱
/equipslot 17 副手武器名或盾牌名稱
若不是狂戰的話, 主手若正裝著雙手武器的話,
直接裝副手是不給裝的,
雖然直接將上面兩行按順序丟進巨集內也可以
但是使用字元實在太多且要常常改主副手名稱
所以個人建議用第三種
第三種:
/equipset 裝備組名稱
這種要配合內建裝備管理員,自行建立
針對武器組合的裝備組,通常會直接用
單單(一心)、雙雙(泰坦)、雙盾(泰坦拿盾)、單盾(武戰防戰)、雙（武戰）
幾種命名,以針對專精調配
例如
/equipset [spec:2]雙雙
或
/equipset [spec:2,noworn:盾牌]雙盾
或
/equipset [nospec:2,noworn:盾牌]單盾
或
/equipset [spec:1]雙
以後變換裝備以只要更動裝備管理員的裝備組內容即可
P.S. 主副手專用裝備組,把其他部位配合ALT鍵選紅
色禁止符號即可, 表示告知系統這些部位不換裝
